File:3D-Link Animated.gif

Summary[edit]

Description3D-Link Animated.gif	Two curves with linking number 4. L8a14. Created with POV-Ray.
Date	7 September 2007, 06:56 (original upload date)
Source	Transferred from en.wikipedia to Commons. by Keyi (talk · contribs).
Author	Original: Jim.belk Animated: MichaelFrey (talk)
Permission (Reusing this file)	Public domainPublic domainfalsefalse   This work has been released into the public domain by its author, Jim.belk, at the English Wikipedia project. This applies worldwide. In case this is not legally possible: Jim.belk grants anyone the right to use this work for any purpose, without any conditions, unless such conditions are required by law. .

Notes[edit]

Made with POVRay

Source Code[edit]

#include "colors.inc"

#declare AxisLength = 3;
#declare FrameWidth = 0.01;

global_settings { assumed_gamma 1.0}

plane {
	<0,0,1>, -4.5
	pigment {color rgb <.9,.9,.9> }
	finish {ambient 0.4 diffuse 0.5}
}

camera {
	location <0.1,0.5,6.0>
	sky <0,0,1>
	right <-1,1,0>/sqrt(2)
	look_at <0,0,0>
}

light_source { <0, -2, 10> color White area_light <1, 0, 0>, <0, 1, 0>, 3, 3 adaptive 1 jitter }

#declare R = 1.5;  // radius to center circle of torus
#declare r = 0.5;  // radius of torus cross-section  
#declare r_tube = 0.1;  // thickness of tube
              
#macro tpoint(theta,phi)
  <(R + r*cos(phi))*cos(theta), (R + r*cos(phi))*sin(theta), r*sin(phi)>
#end

sphere_sweep
  {
  cubic_spline 35,
  #declare Index = 0;
  #while(Index < 35)
    tpoint( (Index-1)*pi/16, (Index-1)*pi/4), r_tube
    #declare Index = Index + 1;
  #end
  finish {phong 1} pigment {color Blue}
  rotate <0,360*clock,0>
  }

sphere_sweep
  {
  cubic_spline 35,
  #declare Index = 0;
  #while(Index < 35)
    tpoint( (Index-1)*pi/16, (Index+3)*pi/4), r_tube
    #declare Index = Index + 1;
  #end
  finish {phong 1} pigment {color Red}
  rotate <0,360*clock,0>
  }