File talk:IQ curve.svg

Half-integer IQ values

The current plot shows half-integer IQ values, which is not correct. I think, the idea was to make it symmetric, but the approach is flawed. Perhaps it would be better to do something like

set terminal svg name 'IQ_curve' size 600,480 font ',10' rounded
set output 'IQ_curve.svg'

mu    = 100.0
sigma = 15.0
from  = 55
to    = 145

# Normal distribution:
# (continuos normalization approximation, good to ~10 digits in this case)
P(x) = exp(-(x - mu)**2 / (2 * sigma**2)) / (sqrt(2 * pi) * sigma) * 100
# By sigma intervals:
oddsi(x) = (int(abs(x - mu) / sigma) % 2) ^ (x < mu)
Pm(x) =               (x == mu)  ? P(x) : 1/0 # sample at mu
Po(x) = ( oddsi(x) && (x != mu)) ? P(x) : 1/0 # samples in odd sigma intervals
Pe(x) = (!oddsi(x) && (x != mu)) ? P(x) : 1/0 # samples in even sigma intervals

set key off
set border 3
set xlabel 'IQ'
set xtics 10 out nomirror
set mxtics 2
set ylabel 'Population, %'
set ytics 1 out nomirror
set mytics 2
set samples (to - from + 1)
set function style impulses
plot [x = from:to] \
 Pm(x) lw 2, \
 Po(x) lw 2, \
 Pe(x) lw 2

which plots a symmetric distribution at integral points and with the mean (=100 here) highlighted?

If there are no objections, I'll replace it.

Mikhail Ryazanov (talk) 00:18, 24 October 2012 (UTC)

I have updated the file and its description. Please let me know if there are any concerns... — Mikhail Ryazanov (talk) 21:38, 2 November 2012 (UTC)

Current version incorrect

2020 version clearly does not show a normal IQ curve anymore (horizontal axis makes no sense and bars appear to be in a wrong order). — Preceding unsigned comment was added by 2A02:908:164:99A0:68CF:70EF:1587:86 (talk) 23:31, 13 August 2020 (UTC)

File rendered wrongly

Please update the rendered image.

The current render of the graph is one-sided and the vast mayority of population scores an IQ well below 50, nobody is above 100. That is clearly wrong.

With the given script on this discussion page, gnuplot outputs an error at "set function style impulses". This is invalid syntax and should read "set style function impulses". With that change gnuplot correctly renders a two-sided graph, centered around IQ=100. Please rerender and upload the image file. I can't overwrite the file myself, because it is locked.