File:Poynting vector Gaussian beam focus.gif

From Wikimedia Commons, the free media repository
Jump to navigation Jump to search

Poynting_vector_Gaussian_beam_focus.gif ‎(494 × 243 pixels, file size: 6.45 MB, MIME type: image/gif, looped, 401 frames, 40 s)

Captions

Captions

Poynting vector for a gaussian beam going through a focus.

Summary[edit]

Description
English: The Poynting vector describes the direction of the local flow of energy, so it points inward before the focus and outward after the focus.

At the focus all the energy is flowing in the same direction, so a "collimated beam" is effectively a very long focus.

(Left: modulus squared. Right: phase)
Date
Source https://twitter.com/j_bertolotti/status/1281605546592874497
Author Jacopo Bertolotti
Permission
(Reusing this file)		 https://twitter.com/j_bertolotti/status/1030470604418428929

Mathematica 12.1 code[edit]

\[Lambda] = 1;
\[Sigma] = 0.3 \[Lambda];
k0 = (2 \[Pi])/\[Lambda];
zR = \[Sigma]^2 k0;
w0 = Sqrt[(\[Lambda] zR)/\[Pi]];
w[z_] := w0 Sqrt[1 + z^2/zR^2];
R[z_] := (zR^2 + z^2)/z;
E2[x_, y_, z_] := w0/w[z] E^(I ArcTan[zR, z]) E^-((x^2 + y^2)/(w[z])^2) E^(I k0 (z + (x^2 + y^2)/(2 R[z])));
f = E2[x, y, z];
psi = f;
S = Abs[E2[x, y, z]]^2 Grad[ArcTan[zR, z] + k0 (z + (x^2 + y^2)/(2 R[z])), {x, y, z}];
p0 = Table[
   abs = DensityPlot[Evaluate[Abs[psi]^2 /. {z -> z1}], {x, -2, 2}, {y, -2, 2}, PlotRange -> All, Frame -> False, ImagePadding -> None, ColorFunction -> "SunsetColors"];
   arg = DensityPlot[Evaluate[Arg[psi] /. {z -> z1}], {x, -2, 2}, {y, -2, 2}, PlotRange -> All, Frame -> False, ImagePadding -> None, ColorFunction -> Hue];
   Grid[{{
      Graphics3D[{
        Texture[abs], 
        Polygon[{{-1, -1, z1}, {1, -1, z1}, {1, 1, z1}, {-1, 1, z1}}, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}]
        , Orange,
        Table[
         If[Norm[Re@S /. {x -> x1, y -> y1, z -> z1}] > 0.1, 
          Arrow[{{x1, y1, z1}, {x1, y1, z1} + (Re[S /. {x -> x1, y -> y1, z -> z1}])/5}] ], {x1, -1, 1, 0.2}, {y1, -1, 1, 0.2}]
        }, Lighting -> "Neutral", PlotRange -> {{-1, 1}, {-1, 1}, {-2, 2.2}}]
      ,
      Graphics3D[{
        Texture[arg], 
        Polygon[{{-1, -1, z1}, {1, -1, z1}, {1, 1, z1}, {-1, 1, z1}}, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}]
        , Black,
        Table[
         If[Norm[Re@S /. {x -> x1, y -> y1, z -> z1}] > 0.1, Arrow[{{x1, y1, z1}, {x1, y1, z1} + (Re[S /. {x -> x1, y -> y1, z -> z1}])/5}] ], {x1, -1, 1, 0.2}, {y1, -1, 1, 0.2}]
        }, Lighting -> "Neutral", 
       PlotRange -> {{-1, 1}, {-1, 1}, {-2, 2.2}}]
      }}]
   , {z1, -2.0005, 2., 0.01}];
ListAnimate[p0]

Licensing[edit]

I, the copyright holder of this work, hereby publish it under the following license:
Creative Commons CC-Zero This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication.
The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.

File history

Click on a date/time to view the file as it appeared at that time.

Date/TimeThumbnailDimensionsUserComment
current08:37, 13 July 2020Thumbnail for version as of 08:37, 13 July 2020494 × 243 (6.45 MB)Berto (talk | contribs)Uploaded own work with UploadWizard

You cannot overwrite this file.

The following page uses this file:

Metadata

This file contains additional information such as Exif metadata which may have been added by the digital camera, scanner, or software program used to create or digitize it. If the file has been modified from its original state, some details such as the timestamp may not fully reflect those of the original file. The timestamp is only as accurate as the clock in the camera, and it may be completely wrong.

Retrieved from "https://commons.wikimedia.org/w/index.php?title=File:Poynting_vector_Gaussian_beam_focus.gif&oldid=705878566"