File:One bubble memory track and loop.png

 /*
 ================================================
 Overview of the loop in a magnetic bubble memory
 ------------------------------------------------
 Created by Søren Peo Pedersen - see my user page
 at http://da.wikipedia.org/wiki/Bruger:Peo
 ================================================
 */
 
 // Here follows the definition of the "broken-off" strip of orthomagnetic "track"
 #declare R=seed(4);   // Random generator for pattern of magnetic "bubbles"
 #declare BubbleRow=union {  // Generate the pattern of bubbles
   #local Count=0;
   #while (Count<10)
     #if (rand(R)>.5)  // Random generator determines present/absent bubble
       cylinder {<.76*Count-3.4,0,0>,<.76*Count-3.4,1,0>,.2} // Draws a bubble
     #end
     #local Count=Count+1;
   #end
   }
 
 #declare OffGuides=pigment {  // Pigment outside the guide pattern
   object {
     BubbleRow
     pigment {color rgb <1,1,1>} // South pole areas outside bubbles
     pigment {color rgb <1,0,0>} // North pole areas inside bubbles
     }
   }
 
 #declare OnGuides=pigment {   // Pigment inside the guide pattern
   object {
     BubbleRow
     pigment {color rgb .6}        // South pole areas outside bubbles
     pigment {color rgb <.6,0,0>}  // North pole areas inside bubbles
     }
   }
 
 #declare RowPattern=pigment { // Employ OnGuides and OffGuides patterns 
   object {                    // to render the combined arrangement of
     union {                   // bubbles and guide patterns
       #local Count=0;
       #while (Count<10)
         box {<-3.7+.76*Count,0,-.07>,<-3.3+.76*Count,1,.07>}    // Horizontal part of "T"
         box {<-3.57+.76*Count,0,-.37>,<-3.43+.76*Count,1,-.07>} // Vertical part of "T"
         box {<-3.2+.76*Count,0,-.07>,<-3.06+.76*Count,1,.37>}   // "I"
         #local Count=Count+1;
       #end
       }
     pigment {OffGuides}
     pigment {OnGuides}
     }
   }
 
 #include "functions.inc"  // Needed for function "f_granite" below
 
 isosurface {  // Create the orthomagnetic "slab" with the jagged, "broken-off edges
   function {-f_granite(.05*x,2,.05*z)*1+abs(z)-.5 }  // Makes the jagged edges
   contained_by { box {<-4,-.3,-4>,<4,.3,4>} }  // The box shape that's "broken"
   accuracy 0.0 max_gradient 4
   pigment {
     gradient y
     pigment_map {
       [0 color rgb <1,0,0>]
       [1 RowPattern]
       }
     translate <0,-.5,0>
     scale <1,.6001,1>
     }
   finish {ambient .5}
   }
 
 #declare Coil=merge { // Pair of coils, one above the other
   #local Count=0;   // Counting loop going
   #while (Count<10) // from 0 thru 9
     torus {.2,.03 translate <0,.06*Count+.33,0>}  // A ring in upper coil
     torus {.2,.03 translate <0,.06*Count-.84,0>}  // A ring in lower coil
     #local Count=Count+1;
   #end
   pigment {color rgb 0}       // No color here, it's all in the reflection
   finish {
     metallic                  // Apply metallic effect
     reflection rgb <1,.8,.6>  // Reflects the characteristic copper-red
     phong 1                   // Specular highlights on
     }
   }
 
 #object {Coil translate <-3.9,0,0>} // Electromagnet at left end
 #object {Coil translate <3.9,0,0>}  // Detection coil at right end
 
 // Here follows the code for the circuitry "underneath" the orthomagnetic strip:
 
 union {
   cylinder {<4,-.5,0>,<4,-2.5,0>,.05} // Straight bit down from detection coil
   cylinder {<4,-2.5,-.05>,<4,-2.5,.05>,.1}  // Junction between amplifier and output
   cylinder {<5,-2.5,-.05>,<5,-2.5,.05>,.2}  // The output terminal
   cylinder {<5,-2.5,0>,<-3.5,-2.5,0>,.05} // Straight through the green amplifier
   cylinder {<-3.5,-2.5,-.05>,<-3.5,-2.5,.05>,.1}  // Amplifier "side" in the switch
   cylinder {<-4,-.5,0>,<-4,-1.3,0>,.05} // Straight bit down from electromagnet at left
   cylinder {<-4,-1.3,-.05>,<-4,-1.3,.05>,.1}  // Pivot point in read/write switch
   union {
     cylinder {0,<0,-.8,0>,.05} // The "arm" in the switch
     intersection {  // Arrohead at end of switch "arm"
       box {<0,0,-.05>,<1,1,.05> rotate <0,0,45> scale <1,2,1> translate <0,-1.2,0>}
       plane {<0,1,0,>,-.8}
       }
     //rotate <0,0,22.619865>  // You can change sign on the 22.61... to flip the switch
     translate <-4,-1.3,0> // Move switch arm into position
     }
   cylinder {<-4.5,-2.5,-.05>,<-4.5,-2.5,.05>,.1}  // "New-data side" in the switch
   cylinder {<-6,-2.5,0>,<-4.5,-2.5,0>,.05}  // Entryway for new data from the input
   cylinder {<-6,-2.5,-.05>,<-6,-2.5,.05>,.2}  // The input terminal
   
   pigment {color rgb .5}  // Wiring is grey
   finish {ambient .5}
   }
 
 prism { // The green triangular amplifier/conditioner circuit
   linear_sweep linear_spline
   -0.2,0.2,3,<1.5,-1>,<1.5,1>,<-1.5,0>
   pigment {color rgb <.4,.8,0>}
   finish {ambient .5}
   rotate <90,0,0>
   translate <.5,-2.5,0>
   }
 
 // Here follows the code for the blue arrows indicating the data "traffic" in the system:
 
 #declare Arrow=merge {  // Define an arrow...
   difference {  // The tip
     box {<-1,0,-.001>,<0,1,.001> rotate <0,0,45> scale <4,1,1> translate <.4,0,0>}
     plane {<1,0,0>,0}
     translate <.1,0,0>
     }
   box {<-.5,-.03,-.001>,<.1,.03,.001>}  // The "stem" of the arrow
   pigment {color rgb <0,.5,1>}  // Light blue color
   finish {ambient .5}
   no_shadow // Arrows cast no shadow on their surroundings
   }
 
 #object {Arrow translate <-2.5,1,0>}  // Down along
 #object {Arrow translate <0,1,0>}     // the magne-
 #object {Arrow translate <2.5,1,0>}   // tic track
 
 #object {Arrow rotate <0,0,-90> translate <3.8,-1.6,0>}   // Down below det. coil
 
 #object {Arrow translate <4.8,-2.1,0>}   // Right towards output terminal
 #object {Arrow scale <-1,1,1> translate <2.8,-2.2,0>}   // Left into amplifier triangle
 #object {Arrow scale <-1,1,1> translate <-2.5,-2.2,0>}  // Left out of the amplifier
 
 #object {Arrow translate <-5,-2.2,0>}  // Right in from the input terminal
 #object {Arrow rotate <0,0,90> translate <-3.7,-1.5,0>}   // Down below det. coil
 
 background {color rgb 1}  // White background
 
 camera {  // See everything ...
   location <5,4,-7>   // from this vantage point
   look_at <1,-1.1,0>  // looking towards this point
   up <0,1,0> right <1.6,0,0>  // Force 1:1.6 "landscape" aspect.
   angle 52  // Tweak field-of-view to fit the motif
   }
 
 light_source {    // Illumination from some distance
   <-100,150,-120> // to the left of the scenario
   color rgb 1
   }