File:Barbell POV-Ray.png

// Author: Karl Ostmo
// Date: 2/13/2011
// Version: 1.0
//
// Units in inches
// Sky include obtained from:
// http://povray.tashcorp.net/library/sky_sphere/realskies.inc

#include "colors.inc"
#include "textures.inc"
#include "metals.inc"
#include "realskies.inc"
 
#declare camera_pos = 60;
#declare bar_length = 84;	// 7 Feet
#declare half_bar_length = bar_length/2;

#declare grip_offset = 6;

#declare plate_annulus_radius = 1.5;
#declare flange_radius = 1.5*plate_annulus_radius;
#declare bar_radius = plate_annulus_radius/2;
#declare flange_length = 2;
#declare plate_extension_length = 18;
#declare grip_length = 6;

#declare flange_start = half_bar_length - (flange_length + plate_extension_length);

camera {
	location <-camera_pos/5, -camera_pos, 3/4*camera_pos>
	look_at 0
}

plane {
	<0, 0, 1>, -flange_radius
	pigment {
		White
	}
}

light_source {
	<0, 0, 20*camera_pos>
	color 1.4*White
}

sky_sphere {
    sky_realsky_04
}

#declare half_shape = merge {

	merge {

		cylinder {
			0, x*grip_offset, bar_radius
		}

		cylinder {
			x*(grip_offset + grip_length), x*flange_start, bar_radius
		}

		pigment {
			Gray45
		}
	}

	// Grip
	cylinder {
		x*grip_offset, x*(grip_offset + grip_length), bar_radius

		pigment {
			Gray70
		}
	}

	merge {

		cylinder {
			x*flange_start, x*half_bar_length, plate_annulus_radius
		}

		// Flange
		cylinder {
			x*flange_start, x*(flange_start + flange_length), flange_radius
		}

		texture {T_Silver_4E}
	}
}

merge {
	object{
		half_shape
		scale -1*x
	}

	object{ half_shape }
}