File:Anzahl der Hungernden weltweit ab 2000.svg

#!/usr/bin/gnuplot
# gnuplot 


# Daten per Here-Document
# (siehe Abschntt 'Inline data and datablocks' in
# http://www.gnuplot.info/docs_5.2/Gnuplot_5.2.pdf )
#
$my_HD_1 << EndOfData_1
#
# Quelle: Graph in 
# http://www.fao.org/state-of-food-security-nutrition/en/
#
#
# Spalte 1: Jahr 
# Spalte 2: Absolute Anzahl der Hungernden weltweit 
# Spalte 3: Prozentualer Anteil  der hungernden an der steigenden Weltbevölkerung
#
#
2000 ; 900,0 ; 14,7
2001 ; 917,5 ; 14,8
2002 ; 936,3 ; 14,9
2003 ; 947,2 ; 14,9
2004 ; 941,7 ; 14,6
2005 ; 926,0 ; 14,2
2006 ; 890,9 ; 13,5
2007 ; 854,5 ; 12,8
2008 ; 831,8 ; 12,3
2009 ; 814,7 ; 11,9
2010 ; 794,6 ; 11,5
2011 ; 782,1 ; 11,2
2012 ; 779,3 ; 11,0
2013 ; 775,4 ; 10,8
2014 ; 775,4 ; 10,7
2015 ; 777,0 ; 10,6
2016 ; 815,0 ; 11,0
# EOF
EndOfData_1


# Allgemeines zu den Eingabedaten
set timefmt "%Y"           # Zeitangaben in YYYY
set datafile separator ";" # Spaltenseparator 


# Allgemeines zur Ausgabe
unset key
set style data lines
set style fill transparent solid 0.4
set grid
set border 11              # Bit 1 (unten) + Bit 2 (links) + Bit 8 (rechts)


# Bereiche/Format/etc X-Achse 
set xdata time
set xlabel 'Jahr'
set xrange ['1999':'2017']
set xtics '2000', 60 * 60 * 24 * 365.25 * 5
                      #  xtics in Sekunden 
                      # der Beginn der X-Einteilung kann außerhalb xrange
                      # liegen
set mxtics 5
set format x '%Y'     # Beschriftungsformat JJJJ
set xtics nomirror    # Nur unten Skalieren


# Bereiche/Format/etc Y-Achse
set ylabel      'Zahl der Hungernden weltweit in Mio.' textcolor 'dark-blue'
set yrange      [400:1000]
set ytics       100 textcolor 'dark-blue'
set decimalsign locale "de_DE.utf8"
set decimal     locale "de_DE.utf8"
set format      y  "%'.0f"  # Ausgabeformat
set mytics      5
set ytics nomirror


# Bereiche/Format/etc zweite Y-Achse
set y2label 'Anteil der Hungernden an der Weltbevölkerung in %' textcolor 'dark-red'
set y2range     [10:16]
set y2tics      1 textcolor 'dark-red'
set format      y2  "%'.0f"  # Ausgabeformat
set my2tics     2


# Ausgabeformat: Wir erzeugen SVG
# Die Ausgabedaten leiten wir in eine Pipe und sind so bei Namen der
# Ausgabedatei flexibel (Aufruf: Progname.plt > Ausgabe-svg)
set term svg size 800,400 font "Arial,14"
# keine "set output '<Dateiname>'" Angabe


# Erzeugen der Ausgabe 
plot \
  $my_HD_1 using 1:($2) axes x1y1 with linespoints lc 'dark-blue' lt 1 lw 2 pt 7 ps 0.5,\
  $my_HD_1 using 1:($3) axes x1y2 with linespoints lc 'dark-red'  lt 1 lw 2 pt 7 ps 0.5