File:Anderson Localization 1D dynamics.gif

Summary[edit]

Mathematica 11.0 code[edit]

c = 3 10^8; (*speed of light*)

M[n_, k_, 
   d_] := {{Cos[n k d], I c/n Sin[n k d]}, {I n/c Sin[n k d], 
    Cos[n k d]}}; (*transfer matrix*)

Mi[n_, k_, 
   d_] := {{Cos[d k n], -((I c Sin[d k n])/n)}, {-((I n Sin[d k n])/
     c), Cos[d k n]}}; (*Inverse of a transfer matrix*)

t[m_, n0_, n2_] := (2 n0/c)/(
  n2/c m[[1, 1]] - (n0 n2)/c^2 m[[1, 2]] - m[[2, 1]] + 
   n0/c m[[2, 2]]); (*transmission coefficient*)

dim = 200; (*number of layers in the Bragg mirror*)

s = Join[Table[1., 100], RandomReal[{1., 3.}, dim], 
   Table[1., 
    5]];(*Reflective indices of each layer (including some space to \
show the pulse arrive*)
dim = Dimensions[s][[1]];
d = RandomReal[{0.95 10^-6, 1.05 10^-6}, dim]; (*layer thickness in m*)

nstep = 4000;
\[Omega]min = 2.2 10^15;
\[Omega]max = 2.3 10^15;
trasm = Reap[
    For[\[Omega] = \[Omega]min, \[Omega] <= \[Omega]max, \[Omega] = \[Omega] + (\[Omega]max - \[Omega]min)/nstep,
      tm = Apply[Dot, Table[M[s[[j]], \[Omega]/c, d[[j]]], {j, 1, dim}]];
      Sow[N[t[tm, 1, 1]] ];
      ];][[2, 1]];
source = E^(-(1/2) (w - w0)^2 \[Sigma]^2) /. {w0 -> 2.255 10^15, \[Sigma] -> (40 10^-6)/c, a -> 10^12};
sourcel =   Table[source, {w, \[Omega]min, \[Omega]max, (\[Omega]max - \[Omega]min)/nstep}];
field = trasm*sourcel;
freq = Table[j, {j, \[Omega]min, \[Omega]max, (\[Omega]max - \[Omega]min)/nstep}];
fn = Transpose[{field, field/c}];
tmp0 = fn;
ssm = Reap[For[i = dim, i > 0, i--,
      tmp = 
       Table[((Mi[s[[i]], freq/c, d[[i]] ])[[All, All, j]].tmp0[[j]]), {j, 1, nstep}];
      Sow[tmp[[All, 1]]];
      tmp0 = tmp;
      ];][[2, 1]];
fssm = Map[Fourier, ssm]; (*Fourier transform with respect of frequncy to get the time evolution*)
p1 = Table[
   Show[
    ListPlot[2 (s - 1), PlotStyle -> {Red, Thick}, Joined -> True, PlotRange -> {-10, 10}, InterpolationOrder -> 0], ListPlot[{Re@Reverse@fssm[[All, -j]], Abs@Reverse@fssm[[All, -j]], -Abs@Reverse@fssm[[All, -j]]}, Joined -> True, PlotRange -> {-10, 10}, PlotStyle -> {Directive[Orange], Directive[Thick, Black], Directive[Thick, Black]}], Axes -> False, PlotRange -> {-10, 10}, 
    Epilog -> {Text[Style["Random structure", Medium, Bold], {190, 5}], Text[Style["n", Red, Medium, Bold], {307, 3.5}]} ], {j, -15, 400, 1}];
ListAnimate[Drop[p1, {16}], 10]

Licensing[edit]

I, the copyright holder of this work, hereby publish it under the following license:

This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication.

The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission. http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse